Bracmat ... in your browser ...

Write Bracmat expressions in the upper text box. After pressing the evaluate button, the result of the evaluation of your expressions will eventually appear in the lower text box.
Bracmat is a programming language for symbolic computation with an exquisite programming construct for pattern matching. Read the documentation, and see many more examples on rosettacode.org.
For this demo version the C source code in which Bracmat is written, is translated to JavaScript, so the demo runs within the confines of your browser, with all the limitations that follow, such as the inability to read and write files.
Full, more than 100 times faster versions of Bracmat compiled and linked for Windows, macOS and Linux, together with the C source code, can be found on GitHub.

({Dinesman's multiple-dwelling problem. See 
http://rosettacode.org/wiki/Dinesman's_multiple-dwelling_problem#Bracmat}
    
    Baker Cooper Fletcher Miller Smith:?people
  & ( constraints
    =   
      .   !arg
        : ~(? Baker)
        : ~(Cooper ?)
        : ~(Fletcher ?|? Fletcher)
        : ? Cooper ? Miller ?
        : ~(? Smith Fletcher ?|? Fletcher Smith ?)
        : ~(? Cooper Fletcher ?|? Fletcher Cooper ?)
    )
  & ( solution
    =   floors persons A Z person
      .   !arg:(?floors.?persons)
        & (   !persons:
            & constraints$!floors
            & out$("Inhabitants, from bottom to top:" !floors)
            & ~     { The ~ always fails on evaluation. Here, 
failure forces Bracmat to backtrack and find all solutions, not just the
 first one. }
          |   !persons
            :   ?A
                %?`person
                (?Z&solution$(!floors !person.!A !Z))
          )
    )
  & solution$(.!people)
|                   { After outputting all solutions, the lhs of the | 
operator fails. The rhs of the | operator, here an empty string, is the 
final result. }
);